parser ParserDesc:
    ignore:      "[ \t\n\r]+"
    token END:   "$"
    token ATTR:  "<<\\([^>]+\\|>[^>]\\)*>>"
    token ID:    '[a-zA-Z_][a-zA-Z_0-9]*'
    token STR:   
        '\\("\\([^\\"]+\|\\\\.\\)*"\\)\\|\\(\'\\([^\\\']+\|\\\\.\\)*\'\\)'

    rule Parser: "parser" ID ":" Options<<[]>> Tokens<<[]>> Rules<<[]>> END 
                      -> << (ID,Options,Tokens,Rules) >>

    rule Options<<v>>: 
         "option" ":" STR Options<<append(v,eval(STR))>> -> << Options >>
       |                                                 -> << v >>

    rule Tokens<<v>>:
         "token" ID ":" STR Tokens<<append(v,(ID,STR))>>        -> << Tokens >>
       | "ignore"   ":" STR Tokens<<append(v,('#ignore',STR))>> -> << Tokens >>
       |                                                        -> << v >>

    rule Rules<<v>>:
         "rule" ID OptParam ":" Clause Clauses<<[Clause]>>
         Rules<<append(v,(ID,OptParam,Clauses))>>               -> << Rules >>
       |                                                        -> << v >>

    rule Clause: Subs<<[],[]>> "->" Attr 
                 -> << Clause(Subs[0], Subs[1], Attr) >>
    rule Clauses<<v>>: 
         "|" Clause Clauses<<append(v,Clause)>> -> << Clauses >>
       |                                        -> << v >>

    rule Subs<<u,v>>:  
         STR Subs<<append(u,STR), append(v,'')>>              -> << Subs >>
       | ID OptParam Subs<<append(u,ID), append(v,OptParam)>> -> << Subs >>
       |                                                      -> << (u, v) >>

    rule OptParam:
         Attr -> << Attr >>
       |      -> << '' >>
    rule Attr:  ATTR -> << ATTR[2:-2] >>